Pandita: indu — Standard Library

when log [javascript] (message)
  console.log(message);
end log

when get-value [javascript] (selector)
  return document.querySelector(selector).value;
end get-value

when get-text [javascript] (selector)
  return document.querySelector(selector).innerText;
end get-text

begin math
  -- A non-cryptographically secure random number between 0 and limit, exclusive of the limit
  when random [javascript] (limit)
    return Math.floor(Math.random() * limit);
  end random
end math

begin date
  when today [javascript]
    const t = new Date(Date.now());
    return t.toDateString();
  end today

when days-between [javascript] (start, end)
    const s = new Date(Date.parse(start));
    const e = new Date(Date.parse(end));
    const oneDay = 24 * 60 * 60 * 1000;
    return Math.round(Math.abs((e - s) / oneDay));
  end days-since

when days-since(start)
    call days-between with (start: start, end: call today)
  end days-since
end date

begin lists
  when partition(list-of-nos, p, r)
    set x to item p of list-of-nos
    set i to p
    set j to r
    set done to false
    repeat until done
      repeat until (item j of list-of-nos) <= x
        set j to j - 1
      end repeat
      repeat until (item i of list-of-nos) >= x
        set i to i + 1
      end repeat
      if i < j
        set swap to item i of list-of-nos
        set item i of list-of-nos to item j of list-of-nos
        set item j of list-of-nos to swap
      else
        set done to true
      end if
    end repeat
    j
  end partition
  
  when qsort-numbers(list-of-nos, p, r)
    if p < r
      set q to call partition with (list-of-nos: list-of-nos, p: p, r: r)
      call qsort-numbers with (list-of-nos: list-of-nos, p: 1, r: q)
      call qsort-numbers with (list-of-nos: list-of-nos, p: q + 1, r: r)
    end if
  end qsort-numbers

when sort-numbers(list-of-nos)
    call qsort-numbers with (list-of-nos: list-of-nos, p: 1, r: length of list-of-nos)
  end sort-numbers  
end lists

begin apis
  when url-encode(s)
    set e-s to ""
    repeat with c in s
      set esc to c
      if c = " "
        set esc to "%20"
      end if
      if c = "!"
        set esc to "%21"
      end if
      if c = "\""
        set esc to "%22"
      end if
      if c = "#"
        set esc to "%23"
      end if
      if c = "$"
        set esc to "%24"
      end if
      if c = "%"
        set esc to "%25"
      end if
      if c = "&"
        set esc to "%26"
      end if
      if c = "'"
        set esc to "%27"
      end if
      if c = "("
        set esc to "%28"
      end if
      if c = ")"
        set esc to "%29"
      end if
      if c = "*"
        set esc to "%2A"
      end if
      if c = "+"
        set esc to "%2B"
      end if
      if c = ","
        set esc to "%2C"
      end if
      if c = "/"
        set esc to "%2F"
      end if
      if c = ":"
        set esc to "%3A"
      end if
      if c = ";"
        set esc to "%3B"
      end if
      if c = "="
        set esc to "%3D"
      end if
      if c = "?"
        set esc to "%3F"
      end if
      if c = "@"
        set esc to "%40"
      end if
      if c = "["
        set esc to "%5B"
      end if
      if c = "]"
        set esc to "%5D"
      end if
      append esc to e-s
    end repeat
    e-s
  end url-encode
end apis

begin navigator
  when move-to(page)
    !! "nav-mto-" & @ page
  end move-to

when open-url [javascript] (url)
    window.location.href = url;
  end open-url

when show-dialog(container, content)
    make dialog using dialog-panel
    call show-panel of dialog with (dialog-container: container, form-content: content)
    dialog
  end show-dialog
  
  when hide-dialog(container, dialog)
    set i to length of (children of container)
    repeat while i > 0
      if (item i of (children of container)) = dialog
        remove item i of (children of container)
      end if
      set i to i - 1
    end repeat
  end hide-dialog
end navigator

begin g-font
  family is "Raleway"

when font-url
    set url to "family=" & family
    if is-set? weight of me
      append ":wght@" to url
      if is-list? weight of me
        call sort-numbers of lists with (list-of-nos: weight of me)
        repeat with w in weight
          append (w as string) to url
          if not is-last?
            append ";" to url
          end if
        end repeat
      else
        append weight to url
      end if
    end if
    url
  end font-url
end g-font

begin google-font
  <link rel="preconnect" href="https://fonts.googleapis.com"> 
  <link rel="preconnect" href="https://fonts.gstatic.com" crossorigin> 
  <link href="https://fonts.googleapis.com/css2?" & call font-url & "&display=swap" rel="stylesheet">

when font-url
    if is-set? font
      "family=" & font
    else
      set url to ""
      repeat with f in fonts
        append call font-url of f to url
        if not is-last?
          append "&" to url
        end if
      end repeat
      url
    end if
  end font-url
end google-fonts

begin centered
  style
    object-position is "center"
    max-width is "640px"
    margin-left is "auto"
    margin-right is "auto"
    padding is "5px"
  end style
end centered

begin heading
  weight is 600
  style
    font-weight is weight
    font-size is "1.8em"
    margin is "0.75em 0"
  end style
  <h1>#{ text }</h1>
end heading

begin section-heading
  weight is 600
  style
    font-size is "1.4em"
    font-weight is weight
  end style
  <h2>#{ text }</h2>
end section-heading

begin button
  style
    display is "inline-block"
    font-weight is 500
    font-size is "1em"
    border is "solid 1px black"
    border-radius is "0.05em"
    margin is "15px"
    padding is "1% 5%"
  end style
  <button>#{ label }</button>
end button

begin textarea
  text-width is "8em"
  text-height is "auto"
  text-content is ""
  style
    display is "block"
    height is text-height
    width is text-width
    max-width is "90vw"
    border is "solid 1px black"
  end style
  <textarea>#{ text-content }</textarea>
  when change => set text-content to call get-value with (selector: "#" & @me)
end textarea

database text-content
  scope is "app"
end text-content
begin text-block
  default-text is "Text-Block" && id

<p contenteditable="true">#{ (key id of text-content) or default-text }</p>

style
    white-space is "pre-wrap"
  end style

when text
    call get-text with (selector: "#" & @me)
  end text
  when input
    set key id of text-content to call text
  end input
end text-block

begin description
  title-size is "1.2em"
  style
    font-family is "Raleway"
  end style

begin title
    style
      font-size is title-size
      margin is "0 0.25em"
    end style
    <h2>#{ title-text }</h2>
  end title
  using text-block(id: "desc-" & title-text)
    style
      font-size is "0.9em"
      padding is "0 0.125em"
      margin-bottom is "0.25em"
      white-space is "pre-line"
    end style
  end text-block
end description

begin dialog-panel
  begin modal-overlay
    style
      position is "fixed"
      inset is "0px"
      width is "100vw"
      height is "100vh"
      background-color is "#363636"
      opacity is "0.25"
      backdrop-filter is "blur(4px)"
    end style
  end modal-overlay
  begin form
    style
      position is "absolute"
      top is "0px"
      left is "0px"
      bottom is "0px"
      padding is "16px 8px"
      background-color is "white"
      border is "solid 1px black"
    end style
  end form
  when show-panel(dialog-container, form-content)
    append form-content to form
    append me to dialog-container
  end show-panel
end dialog-panel

begin site
  kanit is make using g-font(family: "Kanit", weight: 500)
  raleway is make using g-font(family: "Raleway", weight: 300)
  with google-font(fonts: list with (kanit; raleway))
  with centered

begin heading
    style
      font-family is "Kanit"
      font-weight is 500
      font-size is "2em"
      text-transform is "uppercase"
      margin is "0.5em 0"
    end style
    <h1>The Indu Standard Library</h1>
  end heading

style
    font-family is "Raleway"
    font-weight is 300
  end style

make using description(title-text: "log")
  make using description(title-text: "get-value")
  make using description(title-text: "get-text")
  using description(title-text: "math")
    make using description(title-text: "random", title-size: "1em")
  end description
  using description(title-text: "navigator")
    make using description(title-text: "move-to", title-size: "1em")
    make using description(title-text: "open-url", title-size: "1em")
  end description
  make using description(title-text: "google-font")
  make using description(title-text: "centered")
  make using description(title-text: "text-block")
end site

A new programming language can be a frustrating experience. It's worse when it also doesn't work properly. Indu is still in alpha, so there will be times it just doesn't work. Please tell us when you see something unexpected, we'll happily help you on the path again, or fix the bug if that's what it is.
(It's probably a bug…)