Pandita: gga — Frasier

include Indu from /indu/standard-library

database secrets
  -- Don't do this! The secrets database should be "private" scope.
  -- This database is "app" to allow the example to work for anyone.
  scope is "app"
end database

api omdb
  url is "http://www.omdbapi.com"
  api-key is key "omdb-api-key" of secrets
  
  api title(imdb-id)
    path is "/?apikey=" & api-key & "&i=" & imdb-id
  end title
  api season(imdb-id, season)
    path is "/?apikey=" & api-key & "&i=" & imdb-id & "&season=" & season
  end season
  api episode(imdb-id, season, episode) 
    path is "/?apikey=" & api-key & "&i=" & imdb-id & "&season=" & season & "&episode=" & episode
  end episode
end api

begin site
  with google-font of Indu(fonts: list with (make using g-font of Indu(family: "Raleway")))
  with centered of Indu
  
  style
    font-family is "Raleway"
    font-size is "1.1em"
    line-height is "1.75em"
    margin-top is "2em"
  end style
  
  title is "—"
  season is "-"
  episode is "-"
  plot is "— —"
  
  begin show-title
    <h1>Pick a Frasier</h1>
    style
      font-size is "2em"
      margin-top is "0.75em"
      margin-bottom is "0.75em"
    end style
  end show-title
  begin header
    <h2>#{ season }.#{ episode }: #{ title }</h2>
    style
      font-size is "1.5em"
      margin-top is "0.5em"
      margin-bottom is "0.5em"
    end style
  end header
  
  begin precis
    <p>#{ plot }</p>
    style
      margin-top is "0.5em"
      margin-bottom is "0.5em"
    end style
  end precis
  
  begin button
    <button>Pick!</button>
    
    style
      font-family is "Raleway"
      font-size is "1.25em"
      padding-top is "0.25em"
      padding-bottom is "0.25em"
      padding-left is "1.75em"
      padding-right is "1.75em"
      background-color is "rgba(255, 255, 255, 1)"
      border-radius is "0.125em"
      border-style is "solid"
      border-width is "1px"
      border-color is "rgba(17, 24, 39, 1)"
    end style
    
    when init
      set title to "—"
      set season to "-"
      set episode to "-"
      set plot to "— —"
    end init
  
    when click
      call init
      set frasier to call get of title of omdb with (imdb-id: "tt0106004")
      set total-seasons to (totalSeasons of frasier) as number
      set season to (call random of math of Indu with (limit: total-seasons)) + 1
      set season-info to call get of season of omdb with (imdb-id: "tt0106004", season: season)
      set episode to (call random of math of Indu with (limit: length of Episodes of season-info)) + 1
      set ep-info to call get of episode of omdb with (imdb-id: "tt0106004", season: season, episode: episode)
      set title to Title of ep-info
      set plot to Plot of ep-info
    end click
  end button
end site

A new programming language can be a frustrating experience. It's worse when it also doesn't work properly. Indu is still in alpha, so there will be times it just doesn't work. Please tell us when you see something unexpected, we'll happily help you on the path again, or fix the bug if that's what it is.
(It's probably a bug…)